Wopśimjeśe

# Programěrowańske pśikłady za wóźeńske elementy w dialogowem editorje

Slědujuce pśikłady su nowy dialog z mjenim "Dialog1". Wužywajśo rědy w symbolowej rědce rědow w dialogowem editorje, aby dialog napórał a slědujuce wóźenske elementy pśidał: kontrolny kašćik z mjenim "Kontrolny kašćik 1", pópisańske pólo z mjenim "Pópisańske pólo 1", Tłocašk z mjenim "Tłocašk 1" a lisćinowe pólo z mjenim "Lisćinowe pólo 1".

Źiwajśo pśecej na wjelikopisanje a małopisanje, gaž objektowej wariabli wóźeński element pśipokazujośo.

### Globalna funkcija za zacytanje dialogow

    Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
    Dim oLib as Object ' com.sun.star.script.XLibraryContainer
    Dim oLibDialog as Object
    Dim oRuntimeDialog as Object
        If IsMissing(oLibContainer) Then
            oLibContainer = DialogLibraries
        End If
        oLibContainer.LoadLibrary(LibName)
        oLib = oLibContainer.GetByName(Libname)
        oLibDialog = oLib.GetByName(DialogName)
        oRuntimeDialog = CreateUnoDialog(oLibDialog)
        LoadDialog() = oRuntimeDialog
    End Function

Funkcija LoadDialog se w Tools.ModuleControls składujo, kótaryž jo w Nałožeńske makra a dialogi k dispoziciji.

### Dialog pokazaś

    REM globalna definicija wariblow
    Dim oDialog1 AS Object
    Sub StartDialog1
        With GlobalScope.BasicLibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = Tools.ModuleControls.LoadDialog("Standard", "Dialog1")
        oDialog1.Execute()
    End Sub

### Kakosći wóźeńskich elementow w programje cytaś abo wobźěłaś

    Sub Sample1
        With GlobalScope.Basiclibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = Tools.LoadDialog("Standard", "Dialog1")
        REM Model dialoga wobstaraś
        oDialog1Model = oDialog1.Model
        REM tekst póla Pópisańske pólo 1 pokazaś
        oLabel1 = oDialog1.GetControl("Label1")
        MsgBox oLabel1.Text
        REM nowy tekst za wóźeński element Pópisańske pólo 1 nastajiś
        oLabel1.Text = "Nowe dataje"
        REM modelowe kakosći za wóźeński element Kontrolny kašćik 1 pokazaś
        oCheckBox1Model = oDialog1Model.CheckBox1
        MsgBox oCheckBox1Model.Dbg_Properties
        REM nowy status za Kontrolny kašćik 1 za model wóźeńskego elementa nastajiś
        oCheckBox1Model.State = 1
        REM modelowe kakosći za wóźeński element Tłocašk 1 pokazaś
        oCMD1Model = oDialog1Model.CommandButton1
        MsgBox oCMD1Model.Dbg_Properties
        REM kakosći wóźeńskego elementa Tłocašk 1 pokazaś
        oCMD1 = oDialog1.GetControl("CommandButton1")
        MsgBox oCMD1.Dbg_Properties
        REM dialog wuwjasć
        oDialog1.Execute()
    End Sub

### Lisćinowemu póloju zapisk pśidaś

    Sub AddEntry
        With GlobalScope.Basiclibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = ModuleControls.LoadDialog("Standard", "Dialog1")
        REM pśidawa lisćinowemu póloju nowy zapisk
        oDialog1Model = oDialog1.Model
        oListBox = oDialog1.GetControl("ListBox1")
        Dim iCount as integer
        iCount = oListbox.ItemCount
        oListbox.additem("New Item" & iCount,0)
    End Sub

### Zapisk z lisćinowego póla wótwónoźeś

    Sub RemoveEntry
        With GlobalScope.Basiclibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = Tools.ModuleControls.LoadDialogLoadDialog("Standard", "Dialog1")
        REM prědny zapisk z lisćinowego póla wótwónoźeś
        oDialog1Model = oDialog1.Model
        oListBox = oDialog1.GetControl("ListBox1")
        oListbox.removeitems(0,1)
    End Sub

Pódobne temy

Kakosći wóźeńskich elementow w dialogowem editorje změniś

Dialog Basic napóraś

Wóźeńske elementy w dialogowem editorje napóraś

Dialog z Basic wócyniś

Pšosym pódprějśo nas!